Righe e quadretti

Download per gli impazienti

Dai link seguenti potete scaricare i fogli pronti per la stampa in formato PDF. Per le personalizzazioni ed i perfezionamenti non vi resta che leggere l’intero post dove vi viene illustrato il codice che li realizza.

Pagina a quadretti
Pagina a righe
Carta Millimetrata

La stampa dei file richiede un attimo di attenzione perché il vostro lettore PDF potrebbe adattare la pagina all’area stampabile che è leggermente più piccola per via dei margini. Meglio allora stampare senza che siano settati parametri di adattamento.
Notate anche che le dimensioni dei due file sono veramente minuscole perché non contengono nessun font.

Per scaricare l’articolo intero in PDF cliccate questo link.

Quadretti

Se siete insegnanti di prima elementare (o genitori), può essere utile poter stampare pagine quadrettate per la matematica od a righe per l’italiano.
Ecco allora un simpatico post per inizio anno, in cui disegneremo con Metapost i due fogli desiderati.

Ho misurato le dimensioni di un quaderno a quadretti A4 di prima elementare ottenendo che un quadretto misura 5 mm: cambiando questo parametro all’inizio del sorgente e ricompilando (vedi l’ultimo paragrafo “Note pratiche”), potete ottenere la dimensione del quadretto che volete.

Quaderno a quadretti

Per prima cosa posizioniamo l’origine del sistema di riferimento della figura in basso a destra.
Il codice Metapost è caratterizzato dalle due funzioni hline() e vline() che disegnano rispettivamente linee orizzontali e verticali prendendo tre parametri: l’ordinata (o l’ascissa) della linea, lo spessore ed il colore di penna da usare (le proprietà della penna passate come argomento saranno utili per la stampa della pagina a righe).
Si noti che le coordinate delle linee sono stati corretti di metà dello spessore di linea per produrre una figura esattamente inclusa in una pagina di formato A4.
Infatti, una linea orizzontale larga quanto il foglio A4 e di ordinata per esempio 100mm si scriverebbe semplicemente come nel frammento di codice seguente, ma così la linea uscirebbe di metà spessore utilizzando una penna pencircle. Riportiamo quindi anche il codice per la linea entro pagina:

% linea sbordante di metà spessore agli estremi
draw (0,100mm) -- (210mm,100mm);

% linea entro i margini di pagina
% assumendo che lo spessore della penna sia 1pt
draw (0.5pt,100mm) -- (210mm-0.5pt,100mm);

La griglia a quadretti sarà poi ottenuta con due cicli for, le cui variabili intere determineranno la posizione della linea sul foglio.

% imposta il nome del file di putput contenente il disegno
% come nomefilesorgente.mps
outputtemplate :="%j.mps";

% Quaderno a quadretti
beginfig(1)
   % dimensione di pagina (A4)
   pagewidth := 210mm;
   pageheight:= 297mm;
   
   % dimensione del quadretto
   q := 5mm;
   
   % numero colonne e righe
   nx := floor(pagewidth/q)-1;
   ny := floor(pageheight/q)-1;
   
   % funzione di disegno riga verticale
   def vline(expr x, sp, col)=
      draw (x,0+sp/2)--(x,pageheight-sp/2)
         withpen pencircle scaled sp
         withcolor col;
   enddef;

   % funzione di disegno riga orizzontale
   def hline(expr y, sp, col)=
      draw (0+sp/2,y)--(pagewidth-sp/2,y)
         withpen pencircle scaled sp
         withcolor col;
   enddef;
   
   % loop di disegno righe verticali
   for i=0 upto nx:
      vline(q/2+i*q, 0.32pt, 0.7white);
   endfor;
   
   % loop di disegno righe orizzontali
   for i=0 upto ny:
      hline(q/2+i*q, 0.32pt, 0.7white);
   endfor;
endfig;
end

Righe

Il quaderno a righe per l’italiano della prima elementare è un po’ più complicato perché le righe orizzontali sono diversamente spaziate. L’altezza di una riga è di 19mm con due spaziature da 7mm per avere una riga centrale di 5mm (la figura in alto illustra questo tipo di spaziatura). Inoltre le due righe verticali esterne sono colorate in rosso cupo.

Quaderno a righe (click to download the PDF file)

Nel codice seguente si è assunto un sistema di riferimento con origine nell’angolo in alto a sinistra (semplicemente perché ho misurato il margine superiore di 27.5mm).

outputtemplate :="%j.mps";

% Quaderno a righe
beginfig(1)
   pagewidth := 210mm;
   pageheight:= 297mm;
   
   h1 := 7mm;
   h2 := 5mm;
   hb := 27.5mm;
   
   x1 := 18mm;
   x2 := x1 + 170mm;
   col := 28mm;
   
   % funzione di disegno riga verticale
   def vline(expr x, sp, col)=
      draw (x,-0-sp/2)--(x,-pageheight+sp/2)
         withpen pencircle scaled sp
         withcolor col;
   enddef;

   % funzione di disegno riga orizzontale
   def hline(expr y, sp, col)=
      draw (0+sp/2,y)--(pagewidth-sp/2,y)
         withpen pencircle scaled sp
         withcolor col;
   enddef;
   
   def row(expr y)=
      hline(y-h1, 0.28pt, 0.7white);
      hline(y-h1-h2, 0.28pt, 0.7white);
      hline(y-2*h1-h2, 0.28pt, 0.7white);
   enddef;
   
   vline(x1, 0.32pt, 0.8red);
   vline(x2, 0.32pt, 0.8red);
   
   hline(-hb, 0.28pt, 0.7white);
   
   for i=0 upto 12:
      row(-hb-i*(2*h1+h2));
   endfor;
   
   for i=0 upto 4:
      vline(x1+col+1mm+i*col, 0.28pt, 0.7white);
   endfor;
endfig;
end

Carta millimetrata

Il formato della carta millimetrata prevede una quadrettatura principale ogni centimetro, una secondaria interna ogni 5mm, e la quadrettatura più sottile ad ogni millimetro. L’origine del sistema di riferimento della figura è sempre in alto a sinistra.

Carta millimetrata (click to download)

Prima versione

Nella prima versione del codice l’idea è quella di disegnare le righe orizzontali e verticali nei tre spessori della carta millimetrata con 6 cicli for. Si inizia con le linee sottili poi si reimposta spessore e colore della penna per quelle intermedie e così via. Questo ordine fa in modo che quando le linee verticali ed orizzontali si sovrappongono quelle più scure non vengano segnate con colore meno intenso.
Dal punto di vista del linguaggio di Metapost nel codice si è utilizzato la funzione mod che restituisce il resto della divisione tra i due operandi.

outputtemplate :="%j.mps";

% Foglio di carta millimetrata
%   Origine sistema di riferimento:
%   in alto a sinistra del foglio
beginfig(1)
   u := 1mm;
   pagewidth := 210;
   pageheight:= 297;
      
   % funzione di disegno riga verticale
   def vline(expr x)=
      draw (x*u, -sp/2)--(x*u, -pageheight*u+sp/2);
   enddef;

   % funzione di disegno riga orizzontale
   def hline(expr y)=
      draw (sp/2, y*u)--(pagewidth*u-sp/2, y*u);
   enddef;
   
   % line sottili
   sp:= 0.15pt;
   drawoptions(withpen pencircle scaled sp
               withcolor 0.70white);
   
   for i=1 upto pageheight-1:
      if not (i mod 5 = 0):
         hline( -i );
      fi;
   endfor;
   
   for i=1 upto pagewidth-1:
      if not (i mod 5 = 0):
          vline( i );
      fi;
   endfor;
   
   % linee intermedie
   sp:= 0.30pt;
   drawoptions(withpen pencircle scaled sp
               withcolor 0.55white);
   
   for i=5 step 10 until pageheight-1:
      hline( -i );
   endfor;
   
   for i=5 step 10 until pagewidth-1:
      vline( i );
    endfor;
   
   % linee pesanti ad 1 centimetro
   sp:= 0.42pt;
   drawoptions(withpen pencircle scaled sp
               withcolor 0.45white);
   
   for i=10 step 10 until pageheight-1:
      hline( -i );
   endfor;
   
   for i=10 step 10 until pagewidth-1:
      vline( i );
    endfor;
endfig;
end

Seconda versione

La seconda soluzione utilizza due soli cicli for, uno per le linee orizzontali ed uno per le linee verticali, e lo spessore è di volta in volta regolato da una funzione chiamata importance che in base a quale linea sta per essere disegnata imposta colore e spessore opportuno. La funzione importance rende la soluzione più elegante della precedente con il vantaggio che è immediato regolare il suo costrutto if per ottenere qualsiasi tipo di quadrettatura, per esempio per aggiungere una marcatura ogni 10 centimetri. Tuttavia tracciando prima tutte le righe in una direzione, le righe più chiare nell’altra si sovrappongono a quelle più scure già presenti con un risultato in stampa non perfetto.

outputtemplate :="%j.mps";

% Foglio di carta millimetrata
%   Origine sistema di riferimento:
%   in alto a sinistra del foglio
beginfig(1)
   u := 1mm;
   pagewidth := 210;
   pageheight:= 297;
   
   % funzione di definizione dello spessore
   def importance(expr n)=
      if n mod 10 = 0:
         sp := 0.42pt;
         drawoptions(withcolor 0.425white);
      elseif n mod 5 = 0:
         sp := 0.30pt;
         drawoptions(withcolor 0.550white);
      else:
         sp := 0.15pt;
         drawoptions(withcolor 0.700white);
      fi;
   enddef;
   
   % funzione di disegno riga verticale
   def vline(expr x)=
      importance(x);
      draw (x*u, -sp/2)--(x*u, -pageheight*u+sp/2)
      withpen pencircle scaled sp;
   enddef;

   % funzione di disegno riga orizzontale
   def hline(expr y)=
      importance(y);
      draw (sp/2, y*u)--(pagewidth*u-sp/2, y*u)
      withpen pencircle scaled sp;
   enddef;
   
   for i=1 upto pageheight-1:
      hline( -i );
   endfor;
   
   for i=1 upto pagewidth-1:
      vline( i );
   endfor;
endfig;
end

Note pratiche

Per una prima introduzione a Metapost potete leggerla in questo post, mentre per l’installazione è conveniente installare una distribuzione TeX adatta per il vostro sistema come per esempio TeX Live che vi rifornirà di splendidi programmi liberi e gratuiti come appunto Metapost.
Per installare la TeX Live vi sono molte guide che trovate pure in questo blog, per esempio questa per Ubuntu Linux e questa per Windows.

Per la compilazione dei sorgenti occorre aprire una finestra di comando (o terminale) e digitare il comando mpost nomefile dove nomefile è il file testuale che contiene il codice.
La figura generata da Metapost sarà il file dal nome nomefile.mps che sostanzialmente contiene istruzioni Postscript. Per tradurle nel formato PDF occorre scrivere un file sorgente LaTeX e compilarlo con pdflatex come il seguente (modificare opportunamente il nome del file da includere):

\documentclass{minimal}
% serve l'opzione hiresbb per leggere
% i valori del bounding box di alta
% risoluzione
% l'immagine vettoriale da inserire
% è esattamente un rettangolo A4
\usepackage[hiresbb]{graphicx}
\usepackage[margin=0pt,a4paper]{geometry}
\begin{document}
\noindent\includegraphics{quadri.mps}
\end{document}

In definitiva, la procedura classica per ottenere il PDF comprende due compilazioni la prima con Metapost e la seconda con pdflatex.
Per comodità vi riporto anche uno script in Lua sul cui file basta fare un doppio click per far eseguire tutte le compilazioni (una sorta di make). Perché funzioni i file contenenti il codice Metapost delle figure ed i sorgenti LaTeX per la produzione del PDF, devono essere chiamati come risulta dai commenti iniziali del codice:

#!/usr/bin/lua

--[[
     Quaderno a quadretti:
     quadri.mp (codice Metapost)
     quadri.tex (sorgente LaTeX)

     Quaderno a righe
     righe.mp (codice Metapost)
     righe.tex (sorgente LaTeX)
--]]

-- run metapost (filename without extension):
os.execute("mpost righe")
os.execute("mpost quadri")

-- run pdflatex (filename without extension):
os.execute("pdflatex righe")
os.execute("pdflatex quadri")

-- remove temporary file:
os.remove("righe.log")
os.remove("quadri.log")
os.remove("righe.aux")
os.remove("quadri.aux")
os.remove("righe.mps")
os.remove("quadri.mps")

Alla prossima e Buon Anno 2011!!!